; BLACKJACK.MS2 by Mark Morley (May 22, 1997)
;
; You may copy and modify this program as you see fit.
;
; This program implements the card game known as "Blackjack".  This version
; is a single player one.  The dealer deals two cards for himself, and two
; cards for you.  Face cards (Jacks, Queens, and Kings) are worth 10 points.
; Number cards are worth their numeric value.  Aces are worth either 1 or 11.
; The object is to see who can get the closest to 21 without going over.
; Every time you click on "Hit Me", the dealer gives you another card.  When
; you have gone as high as you dare, click on "Stay".  Then the dealer flips
; over his hidden card and draws as many cards as he likes.  In the event of
; a draw, the dealer wins.


; This function is used to initialize a new deck of cards.  You pass it
; a string which is the variable name used to reference the deck.  This
; particular game only uses one deck, but I may use these routines in
; other card games where I need more than one deck.
;
; I have 52 GIF images of cards in my directory.  "as.gif" is the Ace of
; Spades, "5d.gif" is the Five of Diamonds,"qh.gif" is the Queen of Hearts
; and so on.  There are another 52 GIF images that are "partial" cards
; (ie: they show a thin slice of the left side of each card).  "asp.gif"
; is the (partial) Ace of Spade, for example.  By displaying several partial
; cards beside each other it looks more like a hand of cards and takes less
; screen space.

define initialize( deck )
   varset( deck, 1, "as" )
   varset( deck, 2, "2s" )
   varset( deck, 3, "3s" )
   varset( deck, 4, "4s" )
   varset( deck, 5, "5s" )
   varset( deck, 6, "6s" )
   varset( deck, 7, "7s" )
   varset( deck, 8, "8s" )
   varset( deck, 9, "9s" )
   varset( deck, 10, "ts" )
   varset( deck, 11, "js" )
   varset( deck, 12, "qs" )
   varset( deck, 13, "ks" )
   varset( deck, 14, "ah" )
   varset( deck, 15, "2h" )
   varset( deck, 16, "3h" )
   varset( deck, 17, "4h" )
   varset( deck, 18, "5h" )
   varset( deck, 19, "6h" )
   varset( deck, 20, "7h" )
   varset( deck, 21, "8h" )
   varset( deck, 22, "9h" )
   varset( deck, 23, "th" )
   varset( deck, 24, "jh" )
   varset( deck, 25, "qh" )
   varset( deck, 26, "kh" )
   varset( deck, 27, "ac" )
   varset( deck, 28, "2c" )
   varset( deck, 29, "3c" )
   varset( deck, 30, "4c" )
   varset( deck, 31, "5c" )
   varset( deck, 32, "6c" )
   varset( deck, 33, "7c" )
   varset( deck, 34, "8c" )
   varset( deck, 35, "9c" )
   varset( deck, 36, "tc" )
   varset( deck, 37, "jc" )
   varset( deck, 38, "qc" )
   varset( deck, 39, "kc" )
   varset( deck, 40, "ad" )
   varset( deck, 41, "2d" )
   varset( deck, 42, "3d" )
   varset( deck, 43, "4d" )
   varset( deck, 44, "5d" )
   varset( deck, 45, "6d" )
   varset( deck, 46, "7d" )
   varset( deck, 47, "8d" )
   varset( deck, 48, "9d" )
   varset( deck, 49, "td" )
   varset( deck, 50, "jd" )
   varset( deck, 51, "qd" )
   varset( deck, 52, "kd" )


; This function shuffles a deck of cards.  It does this by selecting 100
; random pairs of cards and swapping them in the deck.  The number 100 is
; arbitrary, but it should be large enough to mix them up a lot.

define shuffle( deck )
   i = 1
   while i < 101
      c1 = random( 1, 52 )
      c2 = random( 1, 52 )
      t = varget( deck, c1 )
      varset( deck, c1, varget( deck, c2 ) )
      varset( deck, c2, t )
      i = i + 1
   endwhile


; This functions draws a random card from the deck.  It also marks that
; card as "DRAWN" so that it cannot be drawn again.

define draw( deck )
   i = 1
   while i < 52
      r = varget( deck, i )
      if r != "DRAWN"
         varset( deck, i, "DRAWN" )
         return r
      endif
      i = i + 1
   endwhile


; In order to remember the current state of the shuffled deck, the dealer's
; hand, the player's hand, etc. this function is used to write all this
; information to a file.

define savedeck( deck, file )
   if output = open( file + ".deck", "w" )
      i = 1
      while i < 53
         write( output, varget( deck, i ), "\n" )
         i = i + 1
      endwhile
      write( output, varget( "dhand", 1 ), "\n" )
      write( output, varget( "dhand", 2 ), "\n" )
      write( output, pnum, "\n" )
      i = 1
      while i <= pnum
         write( output, varget( "phand", i ), "\n" )
         i = i + 1
      endwhile
      close( output )
   endif


; This is the counterpart to the savedeck() function.  It is used to load
; in a previously saved deck, dealer's hand, and player's hand.  It returns
; 0 if it fails and 1 if it succeeds.

define loaddeck( deck, file )
   if input = open( file + ".deck" )
      i = 1
      while i < 53
         varset( deck, i, read( input ) )
         i = i + 1
      endwhile
      dnum = 2
      varset( "dhand", 1, read( input ) )
      varset( "dhand", 2, read( input ) )
      pnum = num( read( input ) )
      i = 1
      while i <= pnum
         varset( "phand", i, read( input ) )
         i = i + 1
      endwhile
      close( input )
      return 1
   endif
   return 0


; This function will add up the card values in the specified hand.  It
; counts aces as 11 and remembers how many aces (if any) are in the hand.
; When it's done it checks to see if the total is over 21.  If so, it
; begins subtracting 10 for each ace in the hand until the total is less
; than or equal to 21 or there are no more aces.  In this way the total is
; always optimal.

define add( hand, num )
   aces = 0
   total = 0
   i = 1
   while i <= num
      c = varget( hand, i )
      t = left( c, 1 )
      if t == "a"
         total = total + 11
         aces = aces + 1
      elif t >= "2" and t <= "9"
         total = total + num( t )
      else
         total = total + 10
      endif
      i = i + 1
   endwhile
   while total > 21 and aces > 0
      total = total - 10
      aces = aces - 1
   endwhile
   return total


; This is the main routine where all the fun begins...

define main

; First we check and see if we are starting a new game or not.  We start a
; new game if the cookie "DECKFILE" is not set, or if the third argument
; to the program is "new" (meaning that the user clicked the "new game"
; button - see below), or if the loaddeck() function fails (presumably
; because somebody deleted the temorary file on us).

   file = getcookie( "DECKFILE" )
   if file == 0 or varget( "arg", 3 ) == "new" or \
         loaddeck( "mydeck", file ) == 0

; Initialize a new deck of cards and shuffle it.

      initialize( "mydeck" )
      shuffle( "mydeck" )

; Set a cookie that contains the file name where the "game in progress"
; will be saved.  In order to get a unique file name we are using the
; time() function to make it.

      file = time( "%Y%d%m%H%M%S" )
      setcookie( "DECKFILE", file )

; Draw two cards for the dealer.  "dnum" keeps track of how many cards
; are in the dealer's hand, and the array "dhand" holds the list of cards.

      dnum = 2
      varset( "dhand", 1, draw( "mydeck" ) )
      varset( "dhand", 2, draw( "mydeck" ) )

; Do the same thing for the player's hand.

      pnum = 2
      varset( "phand", 1, draw( "mydeck" ) )
      varset( "phand", 2, draw( "mydeck" ) )
   endif

; Display a title and begin the screen display.

   print( "<title>M-Script II Blackjack!</title>\n" )
   print( "<body bgcolor=#007700 text=#ffffff alink=#ffff00 vlink=#00ff00>\n" )
   print( "<h1><font color=#ffff00>M-Script II Blackjack!</font></h1>\n" )

; Get and display the total number of games played so far.

   if input = open( "ms2/blackjack.count" )
      count = num( read( input ) ) + 1
      close( input )
   else
      count = 1
   endif
   print( "<h4>Games played so far: ", count, "<h3>\n" )

; If the third argument to the program is "hitme", then the user clicked
; on the "Hit Me" button (see below) and wants another card.

   if varget( "arg", 3 ) == "hitme"
      pnum = pnum + 1
      varset( "phand", pnum, draw( "mydeck" ) )
   endif

; Check the total of the player's hand.  If it is >= 21 or the third
; argument to the program is "stay" (meaning the user clicked on the "Stay"
; button - see below), then the dealer draws repeatedly until his total
; goes over 21 or beats the player.  We set the variable "finished" to
; "TRUE" to indicate that this hand is complete.

   ptotal = add( "phand", pnum )
   if ptotal >= 21 or varget( "arg", 3 ) == "stay"
      dtotal = add( "dhand", dnum )
      while ptotal <= 21 and dtotal < ptotal and dtotal < 21
         dnum = dnum + 1
         varset( "dhand", dnum, draw( "mydeck" ) )
         dtotal = add( "dhand", dnum )
      endwhile
      finished = TRUE
   endif

; If we are finished, display the scores and declare a winner.

   if finished
      print( "<h3>Dealer scored ", dtotal )
      print( ", Player scored ", ptotal, "<br>\n" )
      if dtotal == ptotal
         print( "It's a draw, dealer wins." )
      elif ptotal > 21
         print( "Player busted, dealer wins." )
      elif dtotal > 21
         print( "Dealer busted, player wins." )
      elif ptotal > dtotal
         if ptotal == 21
            print( "Player wins - BLACKJACK!" )
         else
            print( "Player wins." )
         endif
      else
         if dtotal == 21
            print( "Dealer wins - BLACKJACK!" )
         else
            print( "Dealer wins." )
         endif
      endif
      print( "</h3>\n" )
   endif

; Here's where we display the cards themselves.  I'm using a table here
; to make the two hands display side by side (looks nicer).

   print( "<table border=0 width=100%><tr><td><h3>Dealer:</h3>\n" )

; If the game is not finished yet we display the first card in the dealer's
; hand face down.  This means we display the gif file "ep.gif".  We also
; set "i" to 2 to indicate that the "last" card is the second one.  This
; makes more sense when you look at what we do when we *are* finished...

   if not finished
      print( "<img width=20 height=97 src=/mscript/cards/ep.gif>" )
      i = 2


; If we *are* finished the game, display all but the last card using
; partial GIF images.

   else
      i = 1
      while i < dnum
         print( "<img width=20 height=97 src=/mscript/cards/", varget( "dhand", i ), "p.gif>" )
         i = i + 1
      endwhile
   endif

; Display the final card in the dealer's hand.

   print( "<img width=73 height=97 src=/mscript/cards/", varget( "dhand", i ), ".gif>" )

; Now we display the player's hand.

   print( "</td>\n<td><h3>Player: " )

; If we are not finished yet we define two buttons the player can click
; on.  "Hit Me" calls this same program but passes the argument "hitme"
; to it.  Likewise the "Stay" button calls this same program but passes
; it the argument "stay".

   if not finished
      print( "<a href=/cgi-bin/ms2/mark/blackjack/hitme>[Hit Me]</a> " )
      print( "<a href=/cgi-bin/ms2/mark/blackjack/stay>[Stay]</a> " )
   endif

; Whether we are finished or not, this button allows the user to start a
; new game.  It works like the previous two, calling this same program
; but passing the argument "new" to it.

   print( "<a href=/cgi-bin/ms2/mark/blackjack/new>[New Game]</a></h3>\n" )

; Here we display all but the last card in the player's hand as partial
; GIF images (remember I have two sets of 52 images - whole cards and
; "partial" cards).

   i = 1
   while i < pnum
      print( "<img width=20 height=97 src=/mscript/cards/", varget( "phand", i ), "p.gif>" )
      i = i + 1
   endwhile

; Display the last card in the player's hand as a whole card.

   print( "<img width=73 height=97 src=/mscript/cards/", varget( "phand", i ), ".gif>\n" )

; Close the table

   print( "</td></tr></table>" )

; If we aren't finished the game, save it to a file, otherwise delete the
; file.  This isn't perfect.  If the player wanders away in the middle
; of a game it leaves a deck file sitting around.  It's up to me to
; clean out old deck files periodically.  Fortunately I'm using the date
; and time as the file name, so it's easy to spot old ones!

   if not finished
      savedeck( "mydeck", file )
   else
      delete( file + ".deck" )
      lock( "ms2/blackjack.count" )
      if output = open( "ms2/blackjack.count", "w" )
         write( output, count, "\n" )
         close( output )
      endif
      unlock( "ms2/blackjack.count" )
   endif

; Allow the player to return to the M-Script II documentation...

print( "<h3><a href=/mscript/>Return to the M-Script II Documentation</a></h3>" )